*  JieJie Microelectronics P-Spice Model Library
*  Filename	: JMSH1509AC_P v.20210618.txt
*  Product Name      	: JMSH1509AC (TO220-3L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 2.1
*  Release Date	: June 3, 2021
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSH1509AC D G S    
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.0010
RS S 3 1E-006
RG G 17 2
CGS 3 G 3.59E-9
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00496*(TEMP-25))+((-3.08647E-6)*(TEMP-25)^2)}
Gtemp 1 3 VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.81)}
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 0.65E-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
.model NMOS NMOS
+LEVEL = 3                                       
+ VMAX = 1.0752E9               ETA = 1E-4                    
+VTO = 3.319716                TOX = 8E-10                   NSUB = 3.55E15                
+KP = 274.933632               U0 = 424                      KAPPA = 5.856E-10             
+GAMMA = -3.802                PHI = 1.642648                THETA = 1.794907              
+BEX = -2.57                   TCV = 6.56264E-3              DELTA = 160.32725             
.model DCGD D
+CJO = 4.881E-10               VJ = 29.13303                 M = 3.48
.model DSUB D
+IS = 2.49041E-16              N = 0.739023                  RS = 5.27032E-3               
+BV = 155                                          
+xti = 5.421982                
+CJO = 3.26563E-9              VJ = 2.9133E1                 M = 1.665E0                   
.model DLIM D
+IS = 1E-4                     
.ends JMSH1509AC

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************